Acionamento por controle remoto

Arduino: Acionamento por controle remoto

Para o arduíno existe uma biblioteca chamada IRremote que facilta muito na hora de fazer a comunicação através do controle remote infravermelho. Baixe essa biblioteca aqui.

O circuito é formado basicamente por um fototransistor infravermelho. Pode ser utilizado também o sensor IR TSOP1838.

RECUPERANDO O VALOR DE CADA BOTÃO 
Primeiramente, você precisa saber qual valor é enviado para o arduíno quando você pressiona um botâo no controle remoto.

Este código abaixo ( é um dos exemplos da biblioteca IRremote ) faz com que o arduino recebe o sinal do controle remoto e decodifica-o, enviando através da serial.

/*
 * IRremote: IRrecvDump - dump details of IR codes with IRrecv
 * An IR detector/demodulator must be connected to the input RECV_PIN.
 * Version 0.1 July, 2009
 * Copyright 2009 Ken Shirriff
 * http://arcfn.com
 */

#include <IRremote.h>

int RECV_PIN = 5;

IRrecv irrecv(RECV_PIN);

decode_results results;

void setup()
{
  Serial.begin(9600);
  irrecv.enableIRIn(); // Start the receiver
}

// Dumps out the decode_results structure.
// Call this after IRrecv::decode()
// void * to work around compiler issue
//void dump(void *v) {
//  decode_results *results = (decode_results *)v
void dump(decode_results *results) {
  int count = results->rawlen;
  if (results->decode_type == UNKNOWN) {
    Serial.print("Unknown encoding: ");
  }
  else if (results->decode_type == NEC) {
    Serial.print("Decoded NEC: ");
  }
  else if (results->decode_type == SONY) {
    Serial.print("Decoded SONY: ");
  }
  else if (results->decode_type == RC5) {
    Serial.print("Decoded RC5: ");
  }
  else if (results->decode_type == RC6) {
    Serial.print("Decoded RC6: ");
  }
  else if (results->decode_type == PANASONIC) {
    Serial.print("Decoded PANASONIC - Address: ");
    Serial.print(results->panasonicAddress,HEX);
    Serial.print(" Value: ");
  }
  else if (results->decode_type == JVC) {
     Serial.print("Decoded JVC: ");
  }
  Serial.print(results->value, HEX);
  Serial.print(" (");
  Serial.print(results->bits, DEC);
  Serial.println(" bits)");
  Serial.print("Raw (");
  Serial.print(count, DEC);
  Serial.print("): ");

  for (int i = 0; i < count; i++) {
    if ((i % 2) == 1) {
      Serial.print(results->rawbuf[i]*USECPERTICK, DEC);
    }
    else {
      Serial.print(-(int)results->rawbuf[i]*USECPERTICK, DEC);
    }
    Serial.print(" ");
  }
  Serial.println("");
}


void loop() {
  if (irrecv.decode(&results)) {
    Serial.println(results.value, HEX);
    dump(&results);
    irrecv.resume(); // Receive the next value
  }
}

Você verá no monitor serial:

A marcação em verde indica o protocolo de transmissão, no caso, o meu controle remoto utiliza o protocolo NEC;

A marcação em vermelho indica o código enviado pelo controle remoto e o número de bits enviado.

CÓDIGO

Depois de recuperado o valor de cada botão, vamos para o acionamento de leds, o código é muito simples:

#include <IRremote.h>

long value;
int RECV_PIN = 5;//pino para receber o sinal

IRrecv irrecv(RECV_PIN);
decode_results results;//variavel usado pela biblioteca para decodificação

void setup(){
  for(int i=8;i<=13;i++){
   pinMode(i,OUTPUT);
  }
  irrecv.enableIRIn();//habilita o recebimento
}

void loop(){
  if (irrecv.decode(&results)) {//se algum valor foi recebido
    value = results.value;
    irrecv.resume();//prepara-se para a próxima recepção do sinal
   
    if(value==0x807608f7){ digitalWrite(8,!digitalRead(8));  }//botão 1
    if(value==0x80768877){ digitalWrite(9,!digitalRead(9));  }//botão 2
    if(value==0x807648b7){ digitalWrite(10,!digitalRead(10)); }//botão 3
    if(value==0x8076c837){ digitalWrite(11,!digitalRead(11)); }//botão 4
    if(value==0x807628d7){ digitalWrite(12,!digitalRead(12)); }//botão 5
    if(value==0x8076a857){ digitalWrite(13,!digitalRead(13)); }//botão 6
  }

}